35.11. 從Oracle的 PL/SQL 移植

Example 35-4. 從 PL/SQL 向 PL/pgSQL 移植一個簡單的函數

下面是一個Oracle PL/SQL函數：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar,
						 v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW errors;

讓我們讀一遍這個函數然後看看PL/pgSQL與之的不同：

• Oracle可以有 IN，OUT， 和 INOUT 參數傳遞給函數。比如， INOUT 的意思是該參數將接受一個數值並且返回另外一個。 PostgreSQL只有 "IN" 參數，因此沒有這樣的參數類型的聲明。

• 在函數原型裡的 RETURN （不是函數體裡的）關鍵字到了 PostgreSQL 裡就是 RETURNS。還有，IS 變成 AS， 並且您還需要增加一個 LANGUAGE 子句，因為 PL/pgSQL 並非唯一可用的函數語言。

• 在PostgreSQL裡，函數體被認為是一個字串文本， 所以您需要使用單引號或者美元符包圍它，這個包圍符代替了Oracle最後的那個 /。

• 在PostgreSQL裡沒有 show errors 命令，不需要這個命令是因為錯誤是自動報告的。

下面是這個函數移植到PostgreSQL之後的樣子：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name varchar,
						  v_version varchar)
RETURNS varchar AS $$
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
$$ LANGUAGE plpgsql;

Example 35-5. 從PL/SQL 向 PL/pgSQL 移植一個建立其它函數的函數

下面的過程從一個 SELECT 語句中抓取若干行， 然後為了提高效率，又用 IF 語句中的結果製作了一個巨大的函數。 請特別注意在游標和 FOR 循環裡面的不同。

這是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS 
    CURSOR referrer_keys IS 
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    func_cmd varchar(4000); 
BEGIN 
    func_cmd := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR,
                 v_domain IN VARCHAR, v_url IN VARCHAR) RETURN VARCHAR IS BEGIN';

    for referrer_key in referrer_keys loop 
        func_cmd := func_cmd ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ''' || referrer_key.key_string
          || ''' THEN RETURN ''' || referrer_key.referrer_type
          || '''; END IF;';
    END loop; 

    func_cmd := func_cmd || ' RETURN NULL; END;';

    EXECUTE IMMEDIATE func_cmd;
END; 
/ 
show errors;

下面是這個函數在 PostgreSQL 裡面的樣子：

CREATE OR REPLACE FUNCTION cs_update_referrer_type_proc() RETURNS void AS $func$
DECLARE
    referrer_key RECORD;  -- 聲明一個在 FOR 裡用的通用的記錄
    func_body text;
    func_cmd text;
BEGIN 
    func_body := 'BEGIN' ;

    -- 請注意我們是如何在一個 FOR 循環中使用 FOR <record> 構造
    -- 掃瞄各條結果的

    FOR referrer_key IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        func_body := func_body ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ' || quote_literal(referrer_key.key_string)
          || ' THEN RETURN ' || quote_literal(referrer_key.referrer_type)
          || '; END IF;' ;
    END LOOP;

    func_body := func_body || ' RETURN NULL; END;';

    func_cmd :=
      'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host varchar,
                                                        v_domain varchar,
                                                        v_url varchar)
        RETURNS varchar AS '
      || quote_literal(func_body)
      || ' LANGUAGE plpgsql;' ;

    EXECUTE func_cmd;
    RETURN;
END;
$func$ LANGUAGE plpgsql;

請注意函數體是如何獨立製作並且傳遞給 quote_literal，對其中的單引號複製雙份的。 我們需要這個技巧是因為我們無法使用美元符包圍定義新函數：我們沒法保證 referrer_key.key_string 字串過來的字串會解析成什麼樣子。（我們可以假設 referrer_key.kind 可以是只有 host， domain，或者 url，但是 referrer_key.key_string 可能是任何東西， 特別是它可能包含美元符。）這個函數實際上是對原來 Oracle 版本的一個改進， 因為如果在 referrer_key.key_string 或者 referrer_key.referrer_type 包含單引號的時候， 它不會生成有毛病的代碼。

Example 35-6. 從 PL/SQL 向 PL/pgSQL 移植一個字串操作和OUT參數的過程

下面的OraclePL/SQL 過程用於分析一個 URL 並且返回若干個元素 （主機，路徑和命令）。PL/pgSQL函數只能返回一個數值。 一個繞開這個局限的方法是把返回值做成復合類型（行類型）。

下面是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN varchar,
    v_host OUT varchar,  -- 這個變量是要傳回的
    v_path OUT varchar,  -- 這個也是
    v_query OUT varchar) -- 還有這個
IS
    a_pos1 integer;
    a_pos2 integer;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); 

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

下面就是把這個過程翻譯成PostgreSQL可能的樣子：

CREATE TYPE cs_parse_url_result AS (
    v_host VARCHAR,
    v_path VARCHAR,
    v_query VARCHAR
);

CREATE OR REPLACE FUNCTION cs_parse_url(v_url VARCHAR)
RETURNS cs_parse_url_result AS $$
DECLARE
    res cs_parse_url_result;
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    res.v_host := NULL;
    res.v_path := NULL;
    res.v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN res;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        res.v_host := substr(v_url, a_pos1 + 2);
        res.v_path := '/';
        RETURN res;
    END IF;

    res.v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        res.v_path := substr(v_url, a_pos2);
        RETURN res;
    END IF;

    res.v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    res.v_query := substr(v_url, a_pos1 + 1);
    RETURN res;
END;
$$ LANGUAGE plpgsql;

這個函數可以這麼用：

SELECT * FROM cs_parse_url('http://foobar.com/query.cgi?baz');

Example 35-7. 從 PL/SQL 向 PL/pgSQL 移植一個過程

Oracle 版本：

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id in integer)
IS
    a_running_job_count integer;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- free lock(3)
        raise_application_error(-20000, 'Unable to create a new job: a job IS currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    BEGIN
        INSERT INTO cs_jobs(job_id, start_stamp) values(v_job_id, sysdate);
        EXCEPTION 
		WHEN dup_val_on_index THEN NULL; -- 如果已經存在，別擔心
    END;
    COMMIT;
END;
/
show errors

像這樣的過程可以很容易用返回 void 的函數移植到PostgreSQL裡。 我們對這個過程特別感興趣是因為它可以教我們一些東西：

下面是我們把這個過程移植到PL/pgSQL裡的一種方法：

CREATE OR REPLACE FUNCTION cs_create_job(v_job_id integer) RETURNS void AS $$
DECLARE
    a_running_job_count integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        RAISE EXCEPTION 'Unable to create a new job: a job is currently running';(1)
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, now());
    EXCEPTION
        WHEN unique_violation THEN (2)
            -- don't worry if it already exists
    END;

    RETURN;
END;
$$ LANGUAGE plpgsql;