37.11. 從Oracle的 PL/SQL 移植

Example 37-2. 從 PL/SQL 向 PL/pgSQL 移植一個簡單的函數

下面是一個Oracle PL/SQL函數：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW errors;

讓我們讀一遍這個函數然後看看PL/pgSQL與之的不同：

• PostgreSQL 沒有命名的參數。 你必須在自己的函數中明確地給它們取個別名。

• Oracle可以有 IN，OUT， 和 INOUT 參數傳遞給函數。比如， INOUT 的意思是該參數將接受一個數值並且返回另外一個。 PostgreSQL只有 "IN" 參數。

• 在函數原型裡的 RETURN （不是函數體裡的）關鍵字到了 PostgreSQL 裡就是 RETURNS．

• 在PostgreSQL裡，函數是使用單引號做為分隔符創建的， 因此你必須在你的函數體裡逃逸單引號。

• 在PostgreSQL裡沒有 /show errors 命令。

下面是這個函數移植到PostgreSQL之後的樣子：

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(varchar, varchar)
RETURNS varchar AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE plpgsql;

Example 37-3. 從PL/SQL 向 PL/pgSQL 移植一個創建其它函數的函數

下面的過程從一個 SELECT 語句中抓取若幹行， 然後為了提高效率，又用 IF 語句中的結果制作了一個巨大的函數。 請特別注意在遊標和 FOR 循環裡面的不同。

這是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS 
    CURSOR referrer_keys IS 
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    a_output varchar(4000); 
BEGIN 
    a_output := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN varchar, v_domain IN varchar, 
v_url IN varchar) RETURN varchar IS BEGIN'; 

    for referrer_key in referrer_keys loop 
        a_output := a_output || ' IF v_' || referrer_key.kind || ' LIKE ''' || 
referrer_key.key_string || ''' THEN RETURN ''' || referrer_key.referrer_type || 
'''; END IF;'; 
    END loop; 

    a_output := a_output || ' RETURN NULL; END;'; 
    EXECUTE IMMEDIATE a_output; 
END; 
/ 
show errors;

下面是這個函數在 PostgreSQL 裡面的樣子：

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS integer AS '
DECLARE
    referrer_keys RECORD;  -- 聲明一個在 FOR 裡用的通用的記錄
    a_output varchar(4000);
BEGIN 
    a_output := ''CREATE FUNCTION cs_find_referrer_type(varchar,varchar,varchar) 
                  RETURNS varchar AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3;
		     BEGIN ''; 

    -- 請注意我們是如何在一個 FOR 循環中使用 FOR <record> 構造
    -- 掃描各條結果的

    FOR referrer_keys IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        a_output := a_output || '' IF v_'' || referrer_keys.kind || '' LIKE '''''''''' 
                 || referrer_keys.key_string || '''''''''' THEN RETURN '''''' 
                 || referrer_keys.referrer_type || ''''''; END IF;''; 
    END LOOP; 
  
    a_output := a_output || '' RETURN NULL; END; '''' LANGUAGE plpgsql;''; 
 
    -- 這樣是可以 EXECUTE 的原因是因為我們沒有代換任何變量
    -- 否則它可就不能玩了。請查閱 PERFORM 獲取另外一種運行函數的方法
    
    EXECUTE a_output; 
END; 
' LANGUAGE plpgsql;

Example 37-4. 從 PL/SQL 向 PL/pgSQL 移植一個字串操作和OUT參數的過程

下面的OraclePL/SQL 過程用于分析一個 URL 並且返回若幹個元素 （主機，路徑和命令）。PL/pgSQL函數只能返回一個數值。 在 PostgreSQL裡，一個繞開這個局限的方法就是把過程分裂成三個不同的函數： 一個返回主機，另外一個返回路徑，最後一個返回命令。

下面是 Oracle 的版本：

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN varchar,
    v_host OUT varchar,  -- 這個變量是要傳回的
    v_path OUT varchar,  -- 這個也是
    v_query OUT varchar) -- 還有這個
IS
    a_pos1 integer;
    a_pos2 integer;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); 

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

下面就是把這個過程翻譯成PostgreSQL的樣子：

CREATE OR REPLACE FUNCTION cs_parse_url_host(varchar) RETURNS varchar AS ' 
DECLARE 
    v_url ALIAS FOR $1; 
    v_host varchar; 
    v_path varchar; 
    a_pos1 integer; 
    a_pos2 integer; 
    a_pos3 integer; 
BEGIN 
    v_host := NULL; 
    a_pos1 := instr(v_url,''//''); 

    IF a_pos1 = 0 THEN 
        RETURN '''';  -- 返回一個空
    END IF; 

    a_pos2 := instr(v_url,''/'',a_pos1 + 2); 
    IF a_pos2 = 0 THEN 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        RETURN v_host; 
    END IF; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    RETURN v_host; 
END; 
' LANGUAGE plpgsql;

Example 37-5. 從 PL/SQL 向 PL/pgSQL 移植一個過程

Oracle 版本：

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id in integer)
IS
    a_running_job_count integer;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- free lock(3)
        raise_application_error(-20000, 'Unable to create a new job: a job IS currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    BEGIN
        INSERT INTO cs_jobs(job_id, start_stamp) values(v_job_id, sysdate);
        EXCEPTION WHEN dup_val_on_index THEN NULL; -- don't worry IF it already exists(4)
    END;
    COMMIT;
END;
/
show errors

象這樣的過程可以很容易用返回 integer 的 函數移植到PostgreSQL裡．我們對這個過程特別感興趣是因為它可以教我們一些東西：

下面是我們把這個過程移植到PL/pgSQL裡的一種方法：

CREATE OR REPLACE FUNCTION cs_create_job(integer) RETURNS integer AS '
DECLARE
    v_job_id aliAS for $1;
    a_running_job_count integer;
    a_num integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;
    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        RAISE EXCEPTION ''Unable to create a new job: a job IS currently running.'';
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) values(v_job_id);

    SELECT count(*) INTO a_num FROM cs_jobs WHERE job_id=v_job_id;
    IF NOT FOUND THEN  -- If nothing wAS RETURNed in the last query
        -- 該作業不在該表中，因此讓我們把它插入
        INSERT INTO cs_jobs(job_id, start_stamp) values(v_job_id, current_timestamp);
        RETURN 1;
    ELSE
        RAISE NOTICE ''Job already running.'';(1)
    END IF;

    RETURN 0;
END;
' LANGUAGE plpgsql;